GAP (ref) - Chapter 79: Creating New Objects

In the first part, it is explained how to create objects with given type (see 79.1).

In the second part, first a few small examples are given, for dealing with the usual cases of component objects (see 79.2) and positional objects (see 79.3), and for the implementation of new kinds of lists (see 79.4 and 79.7). Finally, the external representation of objects is introduced (see 79.8), as a tool for representation independent access to an object.

The third part deals with some rules concerning the organization of the GAP library; namely, some commands for creating global variables are explained (see 79.10) that correspond to the ones discussed in the first part of the chapter, and the idea of distinguishing declaration and implementation part of GAP packages is outlined (see 79.11).

See also Chapter 81 for examples how the functions from the first part are used, and why it is useful to have a declaration part and an implementation part.

79.1 Creating Objects

79.1-1 Objectify

New objects are created by Objectify. data must be a plain list or a plain record, and type is the type that the desired object shall have. Objectify turns data into an object with type type. That is, data is changed, and afterwards it will not be a list or a record unless type is of type list resp. record.

If data is a list then Objectify turns it into a positional object, if data is a record then Objectify turns it into a component object (for examples, see 79.2 and 79.3).

For examples where Objectify is used, see 79.2, 79.3, and the example in Chapter 81.

79.1-2 ObjectifyWithAttributes

Attribute assignments will change the type of an object. If you create many objects, code of the form

o:=Objectify(type,rec());
SetMyAttribute(o,value);

will take a lot of time for type changes. You can avoid this by setting the attributes immediately while the object is created, as follows. ObjectifyWithAttributes takes a plain list or record obj and turns it an object just like Objectify (79.1-1) and sets attribute attr1 to val1, sets attribute attr2 to val2 and so forth.

If the filter list of type includes that these attributes are set (and the properties also include values of the properties) and if no special setter methods are installed for any of the involved attributes then they are set simultaneously without type changes. This can produce a substantial speedup.

If the conditions of the last sentence are not fulfilled, an ordinary Objectify (79.1-1) with subsequent setter calls for the attributes is performed instead.

79.2 Component Objects

A component object is an object in the representation IsComponentObjectRep (13.4-1) or a subrepresentation of it. Such an object cobj is built from subobjects that can be accessed via cobj!.name, similar to components of a record. Also analogously to records, values can be assigned to components of cobj via cobj!.name:= val. For the creation of component objects, see 79.1. One must be very careful when using the !. operator, in order to interpret the component in the right way, and even more careful when using the assignment to components using !., in order to keep the information stored in cobj consistent.

First of all, in the access or assignment to a component as shown above, name must be among the admissible component names for the representation of cobj, see NewRepresentation (13.4-4). Second, preferably only few low level functions should use !., whereas this operator should not occur in user interactions.

Note that even if cobj claims that it is immutable, i.e., if cobj is not in the category IsMutable (12.6-2), access and assignment via !. and !.:= work. This is necessary for being able to store newly discovered information in immutable objects.

The following example shows the implementation of an iterator (see 30.8) for the domain of integers, which is represented as component object. See 79.3 for an implementation using positional objects. (In practice, such an iterator can be implemented more elegantly using IteratorByFunctions (30.8-8), see 79.6.)

The used succession of integers is 0, 1, -1, 2, -2, 3, -3, ..., that is, a_n = n/2 if n is even, and a_n = (1-n)/2 otherwise.

DeclareRepresentation( "IsIntegersIteratorCompRep",
    IsComponentObjectRep, [ "counter" ] );

The above command creates a new representation (see NewRepresentation (13.4-4)) IsIntegersIteratorCompRep, as a subrepresentation of IsComponentObjectRep (13.4-1), and with one admissible component counter. So no other components than counter will be needed.

InstallMethod( Iterator,
    "method for `Integers'",
    [ IsIntegers ],
    function( Integers )
    return Objectify( NewType( IteratorsFamily,
                                   IsIterator
                               and IsIntegersIteratorCompRep ),
                      rec( counter := 0 ) );
    end );

After the above method installation, one can already ask for Iterator( Integers ). Note that exactly the domain of integers is described by the filter IsIntegers (14.1-2).

By the call to NewType (13.9-3), the returned object lies in the family containing all iterators, which is IteratorsFamily, it lies in the category IsIterator (30.8-3) and in the representation IsIntegersIteratorCompRep; furthermore, it has the component counter with value 0.

What is missing now are methods for the two basic operations of iterators, namely IsDoneIterator (30.8-4) and NextIterator (30.8-5). The former must always return false, since there are infinitely many integers. The latter must return the next integer in the iteration, and update the information stored in the iterator, that is, increase the value of the component counter.

InstallMethod( IsDoneIterator,
    "method for iterator of `Integers'",
    [ IsIterator and IsIntegersIteratorCompRep ],
    ReturnFalse );

InstallMethod( NextIterator,
    "method for iterator of `Integers'",
    [ IsIntegersIteratorCompRep ],
    function( iter )
    iter!.counter:= iter!.counter + 1;
    if iter!.counter mod 2 = 0 then
      return iter!.counter / 2;
    else
      return ( 1 - iter!.counter ) / 2;
    fi;
    end );

79.2-1 NamesOfComponents

For a component object comobj, NamesOfComponents returns a list of strings, which are the names of components currently bound in comobj.

For a record comobj in internal representation, NamesOfComponents returns the result of RecNames (29.1-2).

79.3 Positional Objects

A positional object is an object in the representation IsPositionalObjectRep (13.4-1) or a subrepresentation of it. Such an object pobj is built from subobjects that can be accessed via pobj![pos], similar to positions in a list. Also analogously to lists, values can be assigned to positions of pobj via pobj![pos]:= val. For the creation of positional objects, see 79.1.

One must be very careful when using the ![] operator, in order to interpret the position in the right way, and even more careful when using the assignment to positions using ![], in order to keep the information stored in pobj consistent.

First of all, in the access or assignment to a position as shown above, pos must be among the admissible positions for the representation of pobj, see NewRepresentation (13.4-4). Second, preferably only few low level functions should use ![], whereas this operator should not occur in user interactions.

Note that even if pobj claims that it is immutable, i.e., if pobj is not in the category IsMutable (12.6-2), access and assignment via ![] work. This is necessary for being able to store newly discovered information in immutable objects.

The following example shows the implementation of an iterator (see 30.8) for the domain of integers, which is represented as positional object. See 79.2 for an implementation using component objects, and more details.

DeclareRepresentation( "IsIntegersIteratorPosRep",
    IsPositionalObjectRep, [ 1 ] );

The above command creates a new representation (see NewRepresentation (13.4-4)) IsIntegersIteratorPosRep, as a subrepresentation of IsPositionalObjectRep (13.4-1), and with only the first position being admissible for storing data.

InstallMethod( Iterator,
    "method for `Integers'",
    [ IsIntegers ],
    function( Integers )
    return Objectify( NewType( IteratorsFamily,
                                   IsIterator
                               and IsIntegersIteratorPosRep ),
                      [ 0 ] );
    end );

After the above method installation, one can already ask for Iterator( Integers ). Note that exactly the domain of integers is described by the filter IsIntegers (14.1-2).

By the call to NewType (13.9-3), the returned object lies in the family containing all iterators, which is IteratorsFamily, it lies in the category IsIterator (30.8-3) and in the representation IsIntegersIteratorPosRep; furthermore, the first position has value 0.

InstallMethod( IsDoneIterator,
    "method for iterator of `Integers'",
    [ IsIterator and IsIntegersIteratorPosRep ],
    ReturnFalse );

InstallMethod( NextIterator,
    "method for iterator of `Integers'",
    [ IsIntegersIteratorPosRep ],
    function( iter )
    iter![1]:= iter![1] + 1;
    if iter![1] mod 2 = 0 then
      return iter![1] / 2;
    else
      return ( 1 - iter![1] ) / 2;
    fi;
    end );

It should be noted that one can of course install both the methods shown in Section 79.2 and 79.3. The call Iterator( Integers ) will cause one of the methods to be selected, and for the returned iterator, which will have one of the representations we constructed, the right NextIterator (30.8-5) method will be chosen.

79.4 Implementing New List Objects

This section gives some hints for the quite usual situation that one wants to implement new objects that are lists. More precisely, one either wants to deal with lists that have additional features, or one wants that some objects also behave as lists. An example can be found in 79.5.

A list in GAP is an object in the category IsList (21.1-1). Basic operations for lists are Length (21.17-5), \[\] (21.2-1), and IsBound\[\] (21.2-1) (see 21.2).

Note that the access to the position pos in the list list via list[pos] is handled by the call \[\]( list, pos ) to the operation \[\] (21.2-1). To explain the somewhat strange name \[\] of this operation, note that non-alphanumeric characters like [ and ] may occur in GAP variable names only if they are escaped by a \ character.

Analogously, the check IsBound( list[pos] ) whether the position pos of the list list is bound is handled by the call IsBound\[\]( list, pos ) to the operation IsBound\[\] (21.2-1).

For mutable lists, also assignment to positions and unbinding of positions via the operations \[\]\:\= (21.2-1) and Unbind\[\] (21.2-1) are basic operations. The assignment list[pos]:= val is handled by the call \[\]\:\=( list, pos, val ), and Unbind( list[pos] ) is handled by the call Unbind\[\]( list, pos ).

All other operations for lists, e.g., Add (21.4-2), Append (21.4-5), Sum (21.20-26), are based on these operations. This means that it is sufficient to install methods for the new list objects only for the basic operations.

So if one wants to implement new list objects then one creates them as objects in the category IsList (21.1-1), and installs methods for Length (21.17-5), \[\] (21.2-1), and IsBound\[\] (21.2-1). If the new lists shall be mutable, one needs to install also methods for \[\]\:\= (21.2-1) and Unbind\[\] (21.2-1).

One application for this is the implementation of enumerators for domains. An enumerator for the domain D is a dense list whose entries are in bijection with the elements of D. If D is large then it is not useful to write down all elements. Instead one can implement such a bijection implicitly. This works also for infinite domains.

In this situation, one implements a new representation of the lists that are already available in GAP, in particular the family of such a list is the same as the family of the domain D.

But it is also possible to implement new kinds of lists that lie in new families, and thus are not equal to lists that were available in GAP before. An example for this is the implementation of matrices whose multiplication via * is the Lie product of matrices.

In this situation, it makes no sense to put the new matrices into the same family as the original matrices. Note that the product of two Lie matrices shall be defined but not the product of an ordinary matrix and a Lie matrix. So it is possible to have two lists that have the same entries but that are not equal w.r.t. = because they lie in different families.

79.5 Example – Constructing Enumerators

When dealing with countable sets, a usual task is to define enumerations, i.e., bijections to the positive integers. In GAP, this can be implemented via enumerators (see 21.23). These are lists containing the elements in a specified ordering, and the operations Position (21.16-1) and list access via \[\] (21.2-1) define the desired bijection. For implementing such an enumerator, one mainly needs to install the appropriate functions for these operations.

A general setup for creating such lists is given by EnumeratorByFunctions (30.3-4).

If the set in question is a domain D for which a Size (30.4-6) method is available then all one has to do is to write down the functions for computing the n-th element of the list and for computing the position of a given GAP object in the list, to put them into the components ElementNumber and NumberElement of a record, and to call EnumeratorByFunctions (30.3-4) with the domain D and this record as arguments. For example, the following lines of code install an Enumerator (30.3-2) method for the case that D is the domain of rational integers. (Note that IsIntegers (14.1-2) is a filter that describes exactly the domain of rational integers.)

InstallMethod( Enumerator,
    "for integers",
    [ IsIntegers ],
    Integers -> EnumeratorByFunctions( Integers, rec(
                    ElementNumber := function( e, n ) ... end,
                    NumberElement := function( e, x ) ... end ) ) );

The bodies of the functions have been omitted above; here is the code that is actually used in GAP. (The ordering coincides with that for the iterators for the domain of rational integers that have been discussed in 79.2 and 79.3.)

gap> enum:= Enumerator( Integers );
<enumerator of Integers>
gap> Print( enum!.NumberElement, "\n" );
function ( e, x )
    local  pos;
    if not IsInt( x )  then
        return fail;
    elif 0 < x  then
        pos := 2 * x;
    else
        pos := -2 * x + 1;
    fi;
    return pos;
end
gap> Print( enum!.ElementNumber, "\n" );
function ( e, n )
    if n mod 2 = 0  then
        return n / 2;
    else
        return (1 - n) / 2;
    fi;
    return;
end

The situation becomes slightly more complicated if the set S in question is not a domain. This is because one must provide also at least a method for computing the length of the list, and because one has to determine the family in which it lies (see 79.1). The latter should usually not be a problem since either S is nonempty and all its elements lie in the same family –in this case one takes the collections family of any element in S– or the family of the enumerator must be ListsFamily.

An example in the GAP library is an enumerator for the set of k-tuples over a finite set; the function is called EnumeratorOfTuples (16.2-9).

gap> Print( EnumeratorOfTuples, "\n" );
function ( set, k )
    local  enum;
    if k = 0  then
        return Immutable( [ [  ] ] );
    elif IsEmpty( set )  then
        return Immutable( [  ] );
    fi;
    enum
     := EnumeratorByFunctions( CollectionsFamily( FamilyObj( set ) ),
       rec(
          ElementNumber := function ( enum, n )
                local  nn, t, i;
                nn := n - 1;
                t := [  ];
                for i  in [ 1 .. enum!.k ]  do
                    t[i] := RemInt( nn, Length( enum!.set ) ) + 1;
                    nn := QuoInt( nn, Length( enum!.set ) );
                od;
                if nn <> 0  then
                    Error( "<enum>[", n,
                     "] must have an assigned value" );
                fi;
                nn := enum!.set{Reversed( t )};
                MakeImmutable( nn );
                return nn;
            end,
          NumberElement := function ( enum, elm )
                local  n, i;
                if not IsList( elm )  then
                    return fail;
                fi;
                elm := List( elm, function ( x )
                        return Position( enum!.set, x );
                    end );
                if fail in elm or Length( elm ) <> enum!.k  then
                    return fail;
                fi;
                n := 0;
                for i  in [ 1 .. enum!.k ]  do
                    n := Length( enum!.set ) * n + elm[i] - 1;
                od;
                return n + 1;
            end,
          Length := function ( enum )
                return Length( enum!.set ) ^ enum!.k;
            end,
          PrintObj := function ( enum )
                Print( "EnumeratorOfTuples( ", enum!.set, ", ",
                 enum!.k, " )" );
                return;
            end,
          set := Set( set ),
          k := k ) );
    SetIsSSortedList( enum, true );
    return enum;
end

We see that the enumerator is a homogeneous list that stores individual functions ElementNumber, NumberElement, Length, and PrintObj; besides that, the data components S and k are contained.

79.6 Example – Constructing Iterators

Iterators are a kind of objects that is implemented for several collections in the GAP library and which might be interesting also in other cases, see 30.8. A general setup for implementing new iterators is provided by IteratorByFunctions (30.8-8).

All one has to do is to write down the functions for NextIterator (30.8-5), IsDoneIterator (30.8-4), and ShallowCopy (12.7-1), and to call IteratorByFunctions (30.8-8) with this record as argument. For example, the following lines of code install an Iterator (30.8-1) method for the case that the argument is the domain of rational integers.

(Note that IsIntegers (14.1-2) is a filter that describes exactly the domain of rational integers.)

InstallMethod( Iterator,
    "for integers",
    [ IsIntegers ],
    Integers -> IteratorByFunctions( rec(
                    NextIterator:= function( iter ) ... end,
                    IsDoneIterator := ReturnFalse,
                    ShallowCopy := function( iter ) ... end ) ) );

The bodies of two of the functions have been omitted above; here is the code that is actually used in GAP. (The ordering coincides with that for the iterators for the domain of rational integers that have been discussed in 79.2 and 79.3.)

gap> iter:= Iterator( Integers );
<iterator of Integers at 0>
gap> Print( iter!.NextIterator, "\n" );
function ( iter )
    iter!.counter := iter!.counter + 1;
    if iter!.counter mod 2 = 0  then
        return iter!.counter / 2;
    else
        return (1 - iter!.counter) / 2;
    fi;
    return;
end
gap> Print( iter!.ShallowCopy, "\n" );
function ( iter )
    return rec(
        counter := iter!.counter );
end

Note that the ShallowCopy component of the record must be a function that does not return an iterator but a record that can be used as the argument of IteratorByFunctions (30.8-8) in order to create the desired shallow copy.

79.7 Arithmetic Issues in the Implementation of New Kinds of Lists

When designing a new kind of list objects in GAP, defining the arithmetic behaviour of these objects is an issue.

There are situations where arithmetic operations of list objects are unimportant in the sense that adding two such lists need not be represented in a special way. In such cases it might be useful either to support no arithmetics at all for the new lists, or to enable the default arithmetic methods. The former can be achieved by not setting the filters IsGeneralizedRowVector (21.12-1) and IsMultiplicativeGeneralizedRowVector (21.12-2) in the types of the lists, the latter can be achieved by setting the filter IsListDefault (21.12-3). (for details, see 21.12). An example for wrapped lists with default behaviour are vector space bases; they are lists with additional properties concerning the computation of coefficients, but arithmetic properties are not important. So it is no loss to enable the default methods for these lists.

However, often the arithmetic behaviour of new list objects is important, and one wants to keep these lists away from default methods for addition, multiplication etc. For example, the sum and the product of (compatible) block matrices shall be represented as a block matrix, so the default methods for sum and product of matrices shall not be applicable, although the results will be equal to those of the default methods in the sense that their entries at corresponding positions are equal.

So one does not set the filter IsListDefault (21.12-3) in such cases, and thus one can implement one's own methods for arithmetic operations. (Of course can means on the other hand that one must implement such methods if one is interested in arithmetics of the new lists.)

The specific binary arithmetic methods for the new lists will usually cover the case that both arguments are of the new kind, and perhaps also the interaction between a list of the new kind and certain other kinds of lists may be handled if this appears to be useful.

For the last situation, interaction between a new kind of lists and other kinds of lists, GAP provides already a setup. Namely, there are the categories IsGeneralizedRowVector (21.12-1) and IsMultiplicativeGeneralizedRowVector (21.12-2), which are concerned with the additive and the multiplicative behaviour, respectively, of lists. For lists in these filters, the structure of the results of arithmetic operations is prescribed (see 21.13 and 21.14).

For example, if one implements block matrices in IsMultiplicativeGeneralizedRowVector (21.12-2) then automatically the product of such a block matrix and a (plain) list of such block matrices will be defined as the obvious list of matrix products, and a default method for plain lists will handle this multiplication. (Note that this method will rely on a method for computing the product of the block matrices, and of course no default method is available for that.) Conversely, if the block matrices are not in IsMultiplicativeGeneralizedRowVector (21.12-2) then the product of a block matrix and a (plain) list of block matrices is not defined. (There is no default method for it, and one can define the result and provide a method for computing it.)

Thus if one decides to set the filters IsGeneralizedRowVector (21.12-1) and IsMultiplicativeGeneralizedRowVector (21.12-2) for the new lists, on the one hand one loses freedom in defining arithmetic behaviour, but on the other hand one gains several default methods for a more or less natural behaviour.

If a list in the filter IsGeneralizedRowVector (21.12-1) (IsMultiplicativeGeneralizedRowVector (21.12-2)) lies in IsAttributeStoringRep (13.5-5), the values of additive (multiplicative) nesting depth is stored in the list and need not be calculated for each arithmetic operation. One can then store the value(s) already upon creation of the lists, with the effect that the default arithmetic operations will access elements of these lists only if this is unavoidable. For example, the sum of two plain lists of wrapped matrices with stored nesting depths are computed via the method for adding two such wrapped lists, and without accessing any of their rows (which might be expensive). In this sense, the wrapped lists are treated as black boxes.

79.8 External Representation

An operation is defined for elements rather than for objects in the sense that if the arguments are replaced by objects that are equal to the old arguments w.r.t. the equivalence relation = then the result must be equal to the old result w.r.t. =.

But the implementation of many methods is representation dependent in the sense that certain representation dependent subobjects are accessed.

For example, a method that implements the addition of univariate polynomials may access coefficients lists of its arguments only if they are really stored, while in the case of sparsely represented polynomials a different approach is needed.

In spite of this, for many operations one does not want to write an own method for each possible representations of each argument, for example because none of the methods could in fact take advantage of the actually given representations of the objects. Another reason could be that one wants to install first a representation independent method, and then add specific methods as they are needed to gain more efficiency, by really exploiting the fact that the arguments have certain representations.

For the purpose of admitting representation independent code, one can define an external representation of objects in a given family, install methods to compute this external representation for each representation of the objects, and then use this external representation of the objects whenever they occur.

We cannot provide conversion functions that allow us to first convert any object in question to one particular standard representation, and then access the data in the way defined for this representation, simply because it may be impossible to choose such a standard representation uniformly for all objects in the given family.

So the aim of an external representation of an object obj is a different one, namely to describe the data from which obj is composed. In particular, the external representation of obj is not one possible (standard) representation of obj, in fact the external representation of obj is in general different from obj w.r.t. =, first of all because the external representation of obj does in general not lie in the same family as obj.

For example the external representation of a rational function is a list of length two or three, the first entry being the zero coefficient, the second being a list describing the coefficients and monomials of the numerator, and the third, if bound, being a list describing the coefficients and monomials of the denominator. In particular, the external representation of a polynomial is a list and not a polynomial.

The other way round, the external representation of obj encodes obj in such a way that from this data and the family of obj, one can create an object that is equal to obj. Usually the external representation of an object is a list or a record.

Although the external representation of obj is by definition independent of the actually available representations for obj, it is usual that a representation of obj exists for which the computation of the external representation is obtained by just unpacking obj, in the sense that the desired data is stored in a component or a position of obj, if obj is a component object (see 79.2) or a positional object (see 79.3).

To implement an external representation means to install methods for the following two operations.

79.8-1 ExtRepOfObj

ExtRepOfObj returns the external representation of its argument, and ObjByExtRep returns an object in the family fam that has external representation data.

Of course, ObjByExtRep( FamilyObj( obj ), ExtRepOfObj( obj ) ) must be equal to obj w.r.t. the operation \= (31.11-1). But it is not required that equal objects have equal external representations.

Note that if one defines a new representation of objects for which an external representation does already exist then one must install a method to compute this external representation for the objects in the new representation.

79.9 Mutability and Copying

Any GAP object is either mutable or immutable. This can be tested with the function IsMutable (12.6-2). The intended meaning of (im)mutability is a mathematical one: an immutable object should never change in such a way that it represents a different Element. Objects may change in other ways, for instance to store more information, or represent an element in a different way.

Immutability is enforced in different ways for built-in objects (like records, or lists) and for external objects (made using Objectify (79.1-1)).

For built-in objects which are immutable, the kernel will prevent you from changing them. Thus

gap> l := [1,2,4];
[ 1, 2, 4 ]
gap> MakeImmutable(l);
[ 1, 2, 4 ]
gap> l[3] := 5;
Error, List Assignment: <list> must be a mutable list

For external objects, the situation is different. An external object which claims to be immutable (i.e. its type does not contain IsMutable (12.6-2)) should not admit any methods which change the element it represents. The kernel does not prevent the use of !. and ![ to change the underlying data structure. This is used for instance by the code that stores attribute values for reuse. In general, these ! operations should only be used in methods which depend on the representation of the object. Furthermore, we would not recommend users to install methods which depend on the representations of objects created by the library or by GAP packages, as there is certainly no guarantee of the representations being the same in future versions of GAP.

Here we see an immutable object (the group S_4), in which we improperly install a new component.

gap> g := SymmetricGroup(IsPermGroup,4);
Sym( [ 1 .. 4 ] )
gap> IsMutable(g);
false
gap> NamesOfComponents(g);
[ "Size", "NrMovedPoints", "MovedPoints",
  "GeneratorsOfMagmaWithInverses" ]
gap> g!.silly := "rubbish";
"rubbish"
gap> NamesOfComponents(g);
[ "Size", "NrMovedPoints", "MovedPoints",
  "GeneratorsOfMagmaWithInverses", "silly" ]
gap> g!.silly;
"rubbish"

On the other hand, if we form an immutable externally represented list, we find that GAP will not let us change the object.

gap> e := Enumerator(g);
<enumerator of perm group>
gap> IsMutable(e);
false
gap> IsList(e);
true
gap> e[3];
(1,2,4)
gap> e[3] := false;
Error, The list you are trying to assign to is immutable

When we consider copying objects, another filter IsCopyable (12.6-1), enters the game and we find that ShallowCopy (12.7-1) and StructuralCopy (12.7-2) behave quite differently. Objects can be divided for this purpose into three: mutable objects, immutable but copyable objects, and non-copyable objects (called constants).

A mutable or copyable object should have a method for the operation ShallowCopy (12.7-1), which should make a new mutable object, sharing its top-level subobjects with the original. The exact definition of top-level subobject may be defined by the implementor for new kinds of object.

StructuralCopy (12.7-2) is expected to be much less used than ShallowCopy (12.7-1). Applied to a mutable object, it returns a new mutable object which shares no mutable sub-objects with the input. Applied to an immutable object (even a copyable one), it just returns the object. It is not an operation (indeed, it's a rather special kernel function).

gap> e1 := StructuralCopy(e);
<enumerator of perm group>
gap> IsMutable(e1);
false
gap> e2 := ShallowCopy(e);
[ (), (1,4), (1,2,4), (1,3,4), (2,4), (1,4,2), (1,2), (1,3,4,2),
  (2,3,4), (1,4,2,3), (1,2,3), (1,3)(2,4), (3,4), (1,4,3), (1,2,4,3),
  (1,3), (2,4,3), (1,4,3,2), (1,2)(3,4), (1,3,2), (2,3), (1,4)(2,3),
  (1,2,3,4), (1,3,2,4) ]

There are two other related functions: Immutable (12.6-3), which makes a new immutable object which shares no mutable subobjects with its input and MakeImmutable (12.6-4) which changes an object and its mutable subobjects in place to be immutable. It should only be used on new objects that you have just created, and which cannot share mutable subobjects with anything else.

Both Immutable (12.6-3) and MakeImmutable (12.6-4) work on external objects by just resetting the IsMutable (12.6-2) filter in the object's type. This should make ineligible any methods that might change the object. As a consequence, you must allow for the possibility of immutable versions of any objects you create.

So, if you are implementing your own external objects. The rules amount to the following:

79.10 Global Variables in the Library

Global variables in the GAP library are usually read-only in order to prevent them from being overwritten accidentally. See also Section 4.9.

79.10-1 DeclareGlobalName

For global variables, sometimes code needs to reference them before a value can sensibly be assigned to them. For example, consider the following definition of a recursive function:

BindGlobal( "fun", function(n)
  if n > 0 then
    return 2*fun(n-1);
  fi;
  return 1;
end );

The problem with that code is that it triggers a syntax warning about access to an unbound global variable, as fun only gets assigned after the complete statement has been parsed, yet that statement references fun.

To resolve this, one can declare the variable with DeclareGlobalName before assigning it via BindGlobal (4.9-8). This informs GAP that a global variable with the specified name will eventually be defined, and that thus no syntax warnings pertaining to its use should be printed.

We recommend using DeclareGlobalName instead of DeclareGlobalVariable (79.10-2) or DeclareGlobalFunction (79.10-5) whenever possible.

DeclareGlobalName shall be used in the declaration part of the respective package (see 79.11), values can then be assigned to the new variable as usual, preferably via BindGlobal (4.9-8), in the implementation part (again, see 79.11).

79.10-2 DeclareGlobalVariable

For global variables that are not functions, instead of using BindGlobal (4.9-8) one can also declare the variable with DeclareGlobalVariable which creates a new global variable named by the string name.

In the past the main application of this was to allow access to variables before they were assigned. Starting with GAP 4.12 we recommend to instead use DeclareGlobalName (79.10-1) for this kind of problem. The main remaining application for DeclareGlobalVariable is when one needs flushable values.

If used at all, then DeclareGlobalVariable shall be used in the declaration part of the respective package (see 79.11), values can then be assigned to the new variable with InstallValue (79.10-3), InstallFlushableValue (79.10-3) or InstallFlushableValueFromFunction (79.10-3), in the implementation part (again, see 79.11).

79.10-3 InstallValue

InstallValue assigns the value value to the global variable gvar if it was previously declared via DeclareGlobalVariable (79.10-2). InstallFlushableValue does the same but additionally provides that each call of FlushCaches (79.10-4) will assign a structural copy of value to gvar. InstallFlushableValueFromFunction instead assigns the result of func to gvar (func is re-evaluated for each invocation of FlushCaches (79.10-4)

InstallValue does not work if value is an immediate object, i.e., an internally represented small integer or finite field element. It also fails for booleans. Furthermore, InstallFlushableValue works only if value is a list or a record. (Note that InstallFlushableValue makes sense only for mutable global variables.)

79.10-4 FlushCaches

FlushCaches resets the value of each global variable that has been declared with DeclareGlobalVariable (79.10-2) and for which the initial value has been set with InstallFlushableValue (79.10-3) or InstallFlushableValueFromFunction (79.10-3) to this initial value.

FlushCaches should be used only for debugging purposes, since the involved global variables include for example lists that store finite fields and cyclotomic fields used in the current GAP session, in order to avoid that these fields are constructed anew in each call to GF (59.3-2) and CF (60.1-1).

79.10-5 DeclareGlobalFunction

GAP functions that are not operations and that are intended to be called by users should be notified to GAP via DeclareGlobalFunction. DeclareGlobalFunction returns a function that serves as a placeholder for the function that will be installed later. The placeholder will print an error message if it is called. See also DeclareSynonym (79.10-6).

In the past the main application of this was to allow access to variables before they were assigned. Starting with GAP 4.12 we recommend to use DeclareGlobalName (79.10-1)/BindGlobal (4.9-8) instead of DeclareGlobalVariable (79.10-2)/InstallGlobalFunction whenever possible.

If used at all, then DeclareGlobalVariable (79.10-2) shall be used in the declaration part of the respective package (see 79.11).

A global function declared with DeclareGlobalFunction can be given its value func via InstallGlobalFunction; gvar is the global variable (or a string denoting its name) named with the name argument of the call to DeclareGlobalFunction. For example, a declaration like

DeclareGlobalFunction( "SumOfTwoCubes" );

in the declaration part (see Section 79.11) might have a corresponding implementation part of:

InstallGlobalFunction( SumOfTwoCubes, function(x, y) return x^3 + y^3; end);

79.10-6 DeclareSynonym

DeclareSynonym assigns the string name to a global variable as a synonym for value. Two typical intended usages are to declare an and-filter, e.g.

DeclareSynonym( "IsGroup", IsMagmaWithInverses and IsAssociative );

and to provide a previously declared global function with an alternative name, e.g.

DeclareGlobalFunction( "SizeOfSomething" );
DeclareSynonym( "OrderOfSomething", SizeOfSomething );

Note: Before using DeclareSynonym in the way of this second example, one should determine whether the synonym is really needed. Perhaps an extra index entry in the documentation would be sufficient.

When value is actually an attribute then DeclareSynonymAttr should be used; this binds also globals variables Setname and Hasname for its setter and tester, respectively.

DeclareSynonymAttr( "IsField", IsDivisionRing and IsCommutative );
DeclareAttribute( "GeneratorsOfDivisionRing", IsDivisionRing );
DeclareSynonymAttr( "GeneratorsOfField", GeneratorsOfDivisionRing );

79.11 Declaration and Implementation Part

Each package of GAP code consists of two parts, the declaration part that defines the new categories and operations for the objects the package deals with, and the implementation part where the corresponding methods are installed. The declaration part should be representation independent, representation dependent information should be dealt with in the implementation part.

GAP functions that are not operations and that are intended to be called by users should be notified to GAP in the declaration part via DeclareGlobalFunction (79.10-5). Values for these functions can be installed in the implementation part via InstallGlobalFunction (79.10-5).

Whenever both a NewSomething and a DeclareSomething variant of a function exist (see 79.10), the use of DeclareSomething is recommended because this protects the variables in question from being overwritten. Note that there are no functions DeclareFamily and DeclareType since families and types are created dynamically, hence usually no global variables are associated to them. Further note that DeclareRepresentation (13.4-5) is regarded as belonging to the implementation part, because usually representations of objects are accessed only in very few places, and all code that involves a particular representation is contained in one file; additionally, representations of objects are often not interesting for the user, so there is no need to provide a user interface or documentation about representations.

It should be emphasized that declaration means only an explicit notification of mathematical or technical terms or of concepts to GAP. For example, declaring a category or property with name IsInteresting does of course not tell GAP what this shall mean, and it is necessary to implement possibilities to create objects that know already that they lie in IsInteresting in the case that it is a category, or to install implications or methods in order to compute for a given object whether IsInteresting is true or false for it in the case that IsInteresting is a property.

79 Creating New Objects