Date: April 24th, 2012
This is a collection of examples showing how the GAP system [GAP21] can be used to compute information about the generating graphs of finite groups. It includes all examples that were needed for the computational results in [BGL+10].
The purpose of this writeup is twofold. On the one hand, the computations are documented this way. On the other hand, the GAP code shown for the examples can be used as test input for automatic checking of the data and the functions used.
A first version of this document, which was based on GAP 4.4.12, is available in the arXiv at http://arxiv.org/abs/0911.5589v1 since November 2009. The differences between this file and the current document are as follows.
The format of the GAP output was adjusted to the changed behaviour of GAP 4.5.
The records returned by IsomorphismTypeInfoFiniteSimpleGroup (Reference: IsomorphismTypeInfoFiniteSimpleGroup) contain a component "shortname" since GAP 4.11.
The lower bounds computed for the sporadic simple Monster group in Section 4.4-2 have been improved in two steps. First, the existence of exactly one class of maximal subgroups of the type PSL(2, 41) (see [NW13]) and the nonexistence of maximal subgroups with socle PSL(2, 27) (see [Wil10]) have been incorporated. Second, the classification of classes of maximal subgroups of the Monster has been completed in [DLP23]. As a consequence, the nonexistence of maximal subgroups with socle Sz(8) and PSU(3, 8) and the existence of exactly one class of maximal subgroups with the isomorphism types PSL(2, 13).2 and PSU(3, 4).4 have been proved. Note that still not all class fusions of the maximal subgroups are known, and we get only candidates for some primitive permutation characters.
The known information about the primitive permutation characters of the sporadic simple Monster group is available in the data file data/prim_perm_M.json of GAP's library of character tables since the release of CTblLib 1.3.3. The data from this file are used in Section 4.4-2 instead of the explicit list that had been defined in the code in earlier versions.
The purpose of this note is to document the GAP computations that were carried out in order to obtain the computational results in [BGL+10].
In order to keep this note self-contained, we first describe the theory needed, in Section 4.2. The translation of the relevant formulae into GAP functions can be found in Section 4.3. Then Section 4.4 describes the computations that only require (ordinary) character tables in the GAP Character Table Library [Bre24]. Computations using also the groups are shown in Section 4.5.
The examples use the GAP Character Table Library and the GAP Library of Tables of Marks, so we first load these packages in the required versions.
gap> if not CompareVersionNumbers( GAPInfo.Version, "4.5" ) then > Error( "need GAP in version at least 4.5" ); > fi; gap> LoadPackage( "ctbllib", "1.2", false ); true gap> LoadPackage( "tomlib", "1.1.1", false ); true
Let G be a finite noncyclic group and denote by G^× the set of nonidentity elements in G. We define the generating graph Γ(G) as the undirected graph on the vertex set G^× by joining two elements x, y ∈ G^× by an edge if and only if ⟨ x, y ⟩ = G holds. For x ∈ G^×, the vertex degree d(Γ, x) is |{ y ∈ G^×; ⟨ x, y ⟩ = G }|. The closure cl(Γ) of the graph Γ with m vertices is defined as the graph with the same vertex set as Γ, where the vertices x, y are joined by an edge if they are joined by an edge in Γ or if d(Γ, x) + d(Γ, y) ≥ m. We denote iterated closures by cl^(i)(Γ) = cl(cl^(i-1)(Γ)), where cl^(0)(Γ) = Γ.
In the following, we will show that the generating graphs of the following groups contain a Hamiltonian cycle:
Nonabelian simple groups of orders at most 10^7,
groups G containing a unique minimal normal subgroup N such that N has order at most 10^6, N is nonsolvable, and G/N is cyclic,
sporadic simple groups and their automorphism groups.
Clearly the condition that G/N is cyclic for all nontrivial normal subgroups N of G is necessary for Γ(G) being connected, and [BGL+10, Conjecture 1.6] states that this condition is also sufficient. By [BGL+10, Proposition 1.1], this conjecture is true for all solvable groups, and the second entry in the above list implies that this conjecture holds for all nonsolvable groups of order up to 10^6.
The question whether a graph Γ contains a Hamiltonian cycle (i. e., a closed path in Γ that visits each vertex exactly once) can be answered using the following sufficient criteria (see [BGL+10]). Let d_1 ≤ d_2 ≤ ⋯ ≤ d_m be the vertex degrees in Γ.
If d_k ≥ k+1 holds for 1 ≤ k < m/2 then Γ contains a Hamiltonian cycle.
If d_k ≥ k+1 or d_m-k ≥ m-k holds for 1 ≤ k < m/2 then Γ contains a Hamiltonian cycle.
A graph contains a Hamiltonian cycle if and only if its closure contains a Hamiltonian cycle.
Using character-theoretic methods similar to those used to obtain the results in [BGK08] (the computations for that paper are shown in [Breb]), we can compute lower bounds for the vertex degrees in generating graphs, as follows.
Let R be a set of representatives of conjugacy classes of nonidentity elements in G, fix s ∈ G^×, let 𝕄(G,s) denote the set of those maximal subgroups of G that contain s, let 𝕄(G,s)/∼ denote a set of representatives in 𝕄(G,s) w. r. t. conjugacy in G. For a subgroup M of G, the permutation character 1_M^G is defined by
1_M^G(g):= (|G| ⋅ |g^G ∩ M|) / (|M| ⋅ |g^G|),
where g^G = { g^x; x ∈ G }, with g^x = x^-1 g x, denotes the conjugacy class of g in G. So we have 1_M^G(1) = |G|/|M| and thus |g^G ∩ M| = |g^G| ⋅ 1_M^G(g) / 1_M^G(1).
Doubly counting the set { (s^x, M^y); x, y ∈ G, s^x ∈ M^y } yields |M^G| ⋅ |s^G ∩ M| = |s^G| ⋅ |{ M^x; x ∈ G, s ∈ M^x }| and thus |{ M^x; x ∈ G, s ∈ M^x }| = |M^G| ⋅ 1_M^G(s) / 1_M^G(1) ≤ 1_M^G(s). (If M is a maximal subgroup of G then either M is normal in G or self-normalizing, and in the latter case the inequality is in fact an equality.)
Let Π denote the multiset of primitive permutation characters of G, i. e., of the permutation characters 1_M^G where M ranges over representatives of the conjugacy classes of maximal subgroups of G.
Define
δ(s, g^G):= |g^G| ⋅ max{ 0, 1 - ∑_{π ∈ Π} π(g) ⋅ π(s) / π(1) }
and d(s, g^G):= |{ x ∈ g^G; ⟨ s, x ⟩ = G }|, the contribution of the class g^G to the vertex degree of s. Then we have d(Γ(G), s) = ∑_{x ∈ R} d(s, x^G) and
| d(s, g^G) | = | |g^G| - |⋃_{M ∈ M(G,s)} { x ∈ g^G; ⟨ x, s ⟩ ⊆ M }| | ≥ | |g^G| ⋅ max{ 0, 1 - Σ_{M ∈ M(G,s)} 1_M^G(g) / 1_M^G(1) } |
| = | |g^G| ⋅ max{ 0, 1 - Σ_{M ∈ M(G,s)} 1_M^G(g) / 1_M^G(1) } | |
| ≥ | |g^G| ⋅ max{ 0, 1 - Σ_{M ∈ M(G,s)/∼} 1_M^G(g) ⋅ 1_M^G(s) / 1_M^G(1) } | |
| = | δ(s, g^G) |
So δ(s):= ∑_x ∈ R δ(s, x^G) is a lower bound for the vertex degree of s; this bound can be computed if Π is known.
For computing the vertex degrees of the iterated closures of Γ(G), we define d^(0)(s, g^G):= d(s, g^G) and
d^(i+1)(s,g^G):= |g^G| if d^(i)(Г(G),s) + d^(i)(Г(G),g) ≥ |G|-1, and d^(i+1)(s,g^G):= d^(i)(s,g^G) otherwise. Then
δ^(i+1)(s, g^G):= |g^G| if δ^(i)(s) + δ^(i)(g) ≥ |G|-1, δ^(i+1)(s, g^G):= δ^(i)(s, g^G) otherwise, and δ^(i)(s):= ∑_{x ∈ R} δ^(i)(s, x^G), a lower bound for d(cl^(i)(Γ(G)), s) that can be computed if Π is known.
Let us assume that we know lower bounds β(s) for the vertex degrees d(cl^(i)(Γ(G)), s), for some fixed i, and let us choose representatives s_1, s_2, ..., s_l of the nonidentity conjugacy classes of G such that β(s_1) ≤ β(s_2) ≤ ⋯ ≤ β(s_l) holds. Let c_k = |s_k^G| be the class lengths of these representatives.
Then the first c_1 vertex degrees, ordered by increasing size, are larger than or equal to β(s_1), the next c_2 vertex degrees are larger than or equal to β(s_2), and so on.
Then the set of indices in the k-th nonidentity class of G for which Pósa's criterion is not guaranteed by the given bounds is
{ x; c_1 + c_2 + ⋯ + c_k-1 < x ≤ c_1 + c_2 + ⋯ c_k, x < (|G| - 1) / 2, β(s_k) < x+1 }.
This is an interval { L_k, L_k + 1, ..., U_k } with
L_k = max{ 1 + c_1 + c_2 + ⋯ + c_k-1, β(s_k) }
and
U_k = min{ c_1 + c_2 + ⋯ + c_k, ⌊ |G|/2 ⌋ - 1 } .
(Note that the generating graph has m = |G|-1 vertices, and that x < m/2 is equivalent to x ≤ ⌊ |G|/2 ⌋ - 1.)
The generating graph Γ(G) satisfies Pósa's criterion if all these intervals are empty, i. e., if L_k > U_k holds for 1 ≤ k ≤ l.
The set of indices for which Chvátal's criterion is not guaranteed is the intersection of
{ m-k; 1 ≤ m-k < m/2, d_k < k }
with the set of indices for which Pósa's criterion is not guaranteed.
Analogously to the above considerations, the set of indices m-x in the former set for which Chvátal's criterion is not guaranteed by the given bounds and such that x is an index in the k-th nonidentity class of G is
{ m-x; c_1 + c_2 + ⋯ + c_k-1 < x ≤ c_1 + c_2 + ⋯ c_k, 1 ≤ m-x < (|G| - 1) / 2, β(s_k) < x }.
This is again an interval { L^'_k, L^'_k + 1, ..., U^'_k } with
L^'_k = max{ 1, m - ( c_1 + c_2 + ⋯ + c_k ) }
and
U^'_k = min{ m - ( c_1 + c_2 + ⋯ + c_k-1 ) - 1, ⌊ |G|/2 ⌋ - 1, m-1 - β(s_k) } .
The generating graph Γ(G) satisfies Chvátal's criterion if the union of the intervals { L^'_k, L^'_k + 1, ..., U^'_k }, for 1 ≤ k ≤ l is disjoint to the union of the intervals { L_k, L_k + 1, ..., U_k }, for 1 ≤ k ≤ l.
We describe two approaches to compute, for a given group G, vertex degrees for the generating graph of G or lower bounds for them, by calculating exact vertex degrees from G itself (see Section 4.3-1) or by deriving lower bounds for the vertex degrees using just character-theoretic information about G and its subgroups (see Section 4.3-2). Finally, Section 4.3-3 deals with deriving lower bounds of vertex degrees of iterated closures.
In this section, the task is to compute the vertex degrees d(s,g^G) using explicit computations with the group G.
The function IsGeneratorsOfTransPermGroup checks whether the permutations in the list list generate the permutation group G, provided that G is transitive on its moved points. (Note that testing the necessary condition that the elements in list generate a transitive group is usually much faster than testing generation.) This function has been used already in [Breb].
gap> IsGeneratorsOfTransPermGroup:= function( G, list ) > local S; > > if not IsTransitive( G ) then > Error( "<G> must be transitive on its moved points" ); > fi; > S:= SubgroupNC( G, list ); > > return IsTransitive( S, MovedPoints( G ) ) > and Size( S ) = Size( G ); > end;;
The function VertexDegreesGeneratingGraph takes a transitive permutation group G (in order to be allowed to use IsGeneratorsOfTransPermGroup), the list classes of conjugacy classes of G (in order to prescribe an ordering of the classes), and a list normalsubgroups of proper normal subgroups of G, and returns the matrix [ d(s, g^G) ]_s, g of vertex degrees, with rows and columns indexed by nonidentity class representatives ordered as in the list classes. (The class containing the identity element may be contained in classes.)
The following criteria are used in this function.
The function tests the (non)generation only for representatives of C_G(g)-C_G(s)-double cosets, where C_G(g):= { x ∈ G; g x = x g } denotes the centralizer of g in G. Note that for c_1 ∈ C_G(g), c_2 ∈ C_G(s), and a representative r ∈ G, we have ⟨ s, g^c_1 r c_2 ⟩ = ⟨ s, g^r ⟩^c_2. If ⟨ s, g^r ⟩ = G then the double coset D = C_G(g) r C_G(s) contributes |D|/|C_G(g)| to the vertex degree d(s, g^G), otherwise the contribution is zero.
We have d(s, g^G) ⋅ |C_G(g)| = d(g, s^G) ⋅ |C_G(s)|. (To see this, either establish a bijection of the above double cosets, or doubly count the edges between elements of the conjugacy classes of s and g.)
If ⟨ s_1 ⟩ = ⟨ s_2 ⟩ and ⟨ g_1 ⟩ = ⟨ g_2 ⟩ hold then we have d(s_1, g_1^G) = d(s_2, g_1^G) = d(s_1, g_2^G) = d(s_2, g_2^G), so only one of these values must be computed.
If both s and g are contained in one of the normal subgroups given then d(s, g^G) is zero.
If G is not a dihedral group and both s and g are involutions then d(s, g^G) is zero.
gap> BindGlobal( "VertexDegreesGeneratingGraph", > function( G, classes, normalsubgroups ) > local nccl, matrix, cents, powers, normalsubgroupspos, i, j, g_i, > nsg, g_j, gen, pair, d, pow; > > if not IsTransitive( G ) then > Error( "<G> must be transitive on its moved points" ); > fi; > > classes:= Filtered( classes, > C -> Order( Representative( C ) ) <> 1 ); > nccl:= Length( classes ); > matrix:= []; > cents:= []; > powers:= []; > normalsubgroupspos:= []; > for i in [ 1 .. nccl ] do > matrix[i]:= []; > if IsBound( powers[i] ) then > # The i-th row equals the earlier row 'powers[i]'. > for j in [ 1 .. i ] do > matrix[i][j]:= matrix[ powers[i] ][j]; > matrix[j][i]:= matrix[j][ powers[i] ]; > od; > else > # We have to compute the values. > g_i:= Representative( classes[i] ); > nsg:= Filtered( [ 1 .. Length( normalsubgroups ) ], > i -> g_i in normalsubgroups[i] ); > normalsubgroupspos[i]:= nsg; > cents[i]:= Centralizer( G, g_i ); > for j in [ 1 .. i ] do > g_j:= Representative( classes[j] ); > if IsBound( powers[j] ) then > matrix[i][j]:= matrix[i][ powers[j] ]; > matrix[j][i]:= matrix[ powers[j] ][i]; > elif not IsEmpty( Intersection( nsg, normalsubgroupspos[j] ) ) > or ( Order( g_i ) = 2 and Order( g_j ) = 2 > and not IsDihedralGroup( G ) ) then > matrix[i][j]:= 0; > matrix[j][i]:= 0; > else > # Compute $d(g_i, g_j^G)$. > gen:= 0; > for pair in DoubleCosetRepsAndSizes( G, cents[j], > cents[i] ) do > if IsGeneratorsOfTransPermGroup( G, > [ g_i, g_j^pair[1] ] ) then > gen:= gen + pair[2]; > fi; > od; > matrix[i][j]:= gen / Size( cents[j] ); > if i <> j then > matrix[j][i]:= gen / Size( cents[i] ); > fi; > fi; > od; > > # For later, provide information about algebraic conjugacy. > for d in Difference( PrimeResidues( Order( g_i ) ), [ 1 ] ) do > pow:= g_i^d; > for j in [ i+1 .. nccl ] do > if not IsBound( powers[j] ) and pow in classes[j] then > powers[j]:= i; > break; > fi; > od; > od; > fi; > od; > > return matrix; > end );
In this section, the task is to compute the lower bounds δ(s, g^G) for the vertex degrees d(s, g^G) using character-theoretic methods.
We provide GAP functions for computing the multiset Π of the primitive permutation characters of a given group G and for computing the lower bounds δ(s, g^G) from Π.
For many almost simple groups, the GAP libraries of character tables and of tables of marks contain information for quickly computing the primitive permutation characters of the group in question. Therefore, the function PrimitivePermutationCharacters takes as its argument not the group G but its character table T, say. (This function is shown already in [Breb].)
If T is contained in the GAP Character Table Library (see [Bre24]) then the complete set of primitive permutation characters can be easily computed if the character tables of all maximal subgroups and their class fusions into T are known (in this case, we check whether the attribute Maxes (CTblLib: Maxes) of T is bound) or if the table of marks of G and the class fusion from T into this table of marks are known (in this case, we check whether the attribute FusionToTom (CTblLib: FusionToTom) of T is bound). If the attribute UnderlyingGroup (Reference: UnderlyingGroup for tables of marks) of T is bound then the group stored as the value of this attribute can be used to compute the primitive permutation characters. The latter happens if T was computed from the group G; for tables in the GAP Character Table Library, this is not the case by default.
The GAP function PrimitivePermutationCharacters tries to compute the primitive permutation characters of a group using this information; it returns the required list of characters if this can be computed this way, otherwise fail is returned. (For convenience, we use the GAP mechanism of attributes in order to store the permutation characters in the character table object once they have been computed.)
gap> DeclareAttribute( "PrimitivePermutationCharacters", > IsCharacterTable ); gap> InstallOtherMethod( PrimitivePermutationCharacters, > [ IsCharacterTable ], > function( tbl ) > local maxes, i, fus, poss, tom, G; > > if HasMaxes( tbl ) then > maxes:= List( Maxes( tbl ), CharacterTable ); > for i in [ 1 .. Length( maxes ) ] do > fus:= GetFusionMap( maxes[i], tbl ); > if fus = fail then > fus:= PossibleClassFusions( maxes[i], tbl ); > poss:= Set( fus, > map -> InducedClassFunctionsByFusionMap( > maxes[i], tbl, > [ TrivialCharacter( maxes[i] ) ], map )[1] ); > if Length( poss ) = 1 then > maxes[i]:= poss[1]; > else > return fail; > fi; > else > maxes[i]:= TrivialCharacter( maxes[i] )^tbl; > fi; > od; > return maxes; > elif HasFusionToTom( tbl ) then > tom:= TableOfMarks( tbl ); > maxes:= MaximalSubgroupsTom( tom ); > return PermCharsTom( tbl, tom ){ maxes[1] }; > elif HasUnderlyingGroup( tbl ) then > G:= UnderlyingGroup( tbl ); > return List( MaximalSubgroupClassReps( G ), > M -> TrivialCharacter( M )^tbl ); > fi; > > return fail; > end );
The next function computes the lower bounds δ(s, g^G) from the two lists classlengths of conjugacy class lengths of the group G and prim of all primitive permutation characters of G. (The first entry in classlengths is assumed to represent the class containing the identity element of G.) The return value is the matrix that contains in row i and column j the value δ(s, g^G), where s and g are in the conjugacy classes represented by the (i+1)-st and (j+1)-st column of tbl, respectively. So the row sums of this matrix are the values δ(s).
gap> LowerBoundsVertexDegrees:= function( classlengths, prim ) > local sizes, nccl; > > nccl:= Length( classlengths ); > return List( [ 2 .. nccl ], > i -> List( [ 2 .. nccl ], > j -> Maximum( 0, classlengths[j] - Sum( prim, > pi -> classlengths[j] * pi[j] * pi[i] > / pi[1] ) ) ) ); > end;;
In this section, the task is to compute (lower bounds for) the vertex degrees of iterated closures of a generating graph from (lower bounds for) the vertex degrees of the graph itself, and then to check the criteria of Pósa and Chvátal.
The arguments of all functions defined in this section are the list classlengths of conjugacy class lengths for the group G (including the class of the identity element, in the first position) and a matrix bounds of the values d^(i)(s, g^G) or δ^(i)(s, g^G), with rows and columns indexed by nonidentity class representatives s and g, respectively. Such a matrix is returned by the functions VertexDegreesGeneratingGraph or LowerBoundsVertexDegrees, respectively.
The function LowerBoundsVertexDegreesOfClosure returns the corresponding matrix of the values d^(i+1)(s, g^G) or δ^(i+1)(s, g^G), respectively.
gap> LowerBoundsVertexDegreesOfClosure:= function( classlengths, bounds ) > local delta, newbounds, size, i, j; > > delta:= List( bounds, Sum ); > newbounds:= List( bounds, ShallowCopy ); > size:= Sum( classlengths ); > for i in [ 1 .. Length( bounds ) ] do > for j in [ 1 .. Length( bounds ) ] do > if delta[i] + delta[j] >= size - 1 then > newbounds[i][j]:= classlengths[ j+1 ]; > fi; > od; > od; > > return newbounds; > end;;
Once the values d^(i)(s, g^G) or δ^(i)(s, g^G) are known, we can check whether Pósa's or Chvátal's criterion is satisfied for the graph cl^(i)(Γ(G)), using the function CheckCriteriaOfPosaAndChvatal shown below. (Of course a negative result is meaningless in the case that only lower bounds for the vertex degrees are used.)
The idea is to compute the row sums of the given matrix, and to compute the intervals { L_k, L_k + 1, ..., U_k } and { L^'_k, L^'_k + 1, ..., U^'_k } that were introduced in Section 4.2-2.
The function CheckCriteriaOfPosaAndChvatal returns, given the list of class lengths of G and the matrix of (bounds for the) vertex degrees, a record with the components badForPosa (the list of those pairs [ L_k, U_k ] with the property L_k ≤ U_k), badForChvatal (the list of pairs of lower and upper bounds of nonempty intervals where Chvátal's criterion may be violated), and data (the sorted list of triples [ δ(g_k), |g_k^G|, ι(k) ], where ι(k) is the row and column position of g_k in the matrix bounds). The ordering of class lengths must of course be compatible with the ordering of rows and columns of the matrix, and the identity element of G must belong to the first entry in the list of class lengths.
gap> CheckCriteriaOfPosaAndChvatal:= function( classlengths, bounds ) > local size, degs, addinterval, badForPosa, badForChvatal1, pos, > half, i, low1, upp2, upp1, low2, badForChvatal, interval1, > interval2; > > size:= Sum( classlengths ); > degs:= List( [ 2 .. Length( classlengths ) ], > i -> [ Sum( bounds[ i-1 ] ), classlengths[i], i ] ); > Sort( degs ); > > addinterval:= function( intervals, low, upp ) > if low <= upp then > Add( intervals, [ low, upp ] ); > fi; > end; > > badForPosa:= []; > badForChvatal1:= []; > pos:= 1; > half:= Int( size / 2 ) - 1; > for i in [ 1 .. Length( degs ) ] do > # We have pos = c_1 + c_2 + \cdots + c_{i-1} + 1 > low1:= Maximum( pos, degs[i][1] ); # L_i > upp2:= Minimum( half, size-1-pos, size-1-degs[i][1] ); # U'_i > pos:= pos + degs[i][2]; > upp1:= Minimum( half, pos-1 ); # U_i > low2:= Maximum( 1, size-pos ); # L'_i > addinterval( badForPosa, low1, upp1 ); > addinterval( badForChvatal1, low2, upp2 ); > od; > > # Intersect intervals. > badForChvatal:= []; > for interval1 in badForPosa do > for interval2 in badForChvatal1 do > addinterval( badForChvatal, > Maximum( interval1[1], interval2[1] ), > Minimum( interval1[2], interval2[2] ) ); > od; > od; > > return rec( badForPosa:= badForPosa, > badForChvatal:= Set( badForChvatal ), > data:= degs ); > end;;
Finally, the function HamiltonianCycleInfo assumes that the matrix bounds contains lower bounds for the vertex degrees in the generating graph Γ, and returns a string that describes the minimal i with the property that the given bounds suffice to show that cl^(i)(Γ) satisfies Pósa's or Chvátal's criterion, if such a closure exists. If no closure has this property, the string "no decision" is returned.
gap> HamiltonianCycleInfo:= function( classlengths, bounds ) > local i, result, res, oldbounds; > > i:= 0; > result:= rec( Posa:= fail, Chvatal:= fail ); > repeat > res:= CheckCriteriaOfPosaAndChvatal( classlengths, bounds ); > if result.Posa = fail and IsEmpty( res.badForPosa ) then > result.Posa:= i; > fi; > if result.Chvatal = fail and IsEmpty( res.badForChvatal ) then > result.Chvatal:= i; > fi; > i:= i+1; > oldbounds:= bounds; > bounds:= LowerBoundsVertexDegreesOfClosure( classlengths, > bounds ); > until oldbounds = bounds; > > if result.Posa <> fail then > if result.Posa <> result.Chvatal then > return Concatenation( > "Chvatal for ", Ordinal( result.Chvatal ), " closure, ", > "Posa for ", Ordinal( result.Posa ), " closure" ); > else > return Concatenation( "Posa for ", Ordinal( result.Posa ), > " closure" ); > fi; > elif result.Chvatal <> fail then > return Concatenation( "Chvatal for ", Ordinal( result.Chvatal ), > " closure" ); > else > return "no decision"; > fi; > end;;
In this section, we apply the functions introduced in Section 4.3 to character tables of almost simple groups that are available in the GAP Character Table Library.
Our first examples are the sporadic simple groups, in Section 4.4-1, then their automorphism groups are considered in Section 4.4-3. Small alternating and symmetric groups are treated in Section 4.4-4.
For our convenience, we provide a small function that takes as its argument only the character table in question, and returns a string, either "no prim. perm. characters" or the return value of HamiltonianCycleInfo for the bounds computed from the primitive permutation characters.
gap> HamiltonianCycleInfoFromCharacterTable:= function( tbl ) > local prim, classlengths, bounds; > > prim:= PrimitivePermutationCharacters( tbl ); > if prim = fail then > return "no prim. perm. characters"; > fi; > classlengths:= SizesConjugacyClasses( tbl ); > bounds:= LowerBoundsVertexDegrees( classlengths, prim ); > return HamiltonianCycleInfo( classlengths, bounds ); > end;;
The GAP Character Table Library contains the tables of maximal subgroups of all sporadic simple groups except M.
So the function PrimitivePermutationCharacters can be used to compute all primitive permutation characters for 25 of the 26 sporadic simple groups.
gap> spornames:= AllCharacterTableNames( IsSporadicSimple, true, > IsDuplicateTable, false ); [ "B", "Co1", "Co2", "Co3", "F3+", "Fi22", "Fi23", "HN", "HS", "He", "J1", "J2", "J3", "J4", "Ly", "M", "M11", "M12", "M22", "M23", "M24", "McL", "ON", "Ru", "Suz", "Th" ] gap> for tbl in List( spornames, CharacterTable ) do > info:= HamiltonianCycleInfoFromCharacterTable( tbl ); > if info <> "Posa for 0th closure" then > Print( Identifier( tbl ), ": ", info, "\n" ); > fi; > od; M: no prim. perm. characters
It turns out that only for the Monster group, the information available in the GAP Character Table Library is not sufficient to prove that the generating graph contains a Hamiltonian cycle.
Currently we do not know all primitive permutation characters of the Monster group M. The classes of maximal subgroups are classified in [DLP23], but not all their character tables are known, and for some of those with known character table, the permutation character is not uniquely determined by the character tables involved. However, we can compute upper bounds for the values of the primitive permutation characters 1_S^M from the possible class fusions from S into M if the character table of S is known. For the other subgroups S, the permutation characters 1_S^M have been computed with other methods. Using this information, we will show that the generating graph of M satisfies Pósa's criterion.
The list primdata defined below has length 46. The entry at position i is a list of length one or two. If primdata[i] has length one then its unique entry is the identifier of the library character table of the i-th maximal subgroup of M. If primdata[i] has length two then its entries are a string describing the structure of the i-th maximal subgroup S of M and the permutation character 1_S^M.
(The construction of the explicitly given characters in this list will be documented elsewhere. Some of the constructions can be found in Section 8.16.)
gap> dir:= DirectoriesPackageLibrary( "ctbllib", "data" );; gap> filename:= Filename( dir, "prim_perm_M.json" );; gap> primdata:= EvalString( StringFile( filename ) )[2];; gap> Length( primdata ); 46 gap> m:= CharacterTable( "M" );;
We compute upper bounds for the permutation character values in the cases where the characters are not given explicitly. (We could improve this by using additional information about the class fusions, but this will not be necessary.)
gap> s:= "dummy";; # Avoid a message about an unbound variable ... gap> poss:= "dummy";; # Avoid a message about an unbound variable ... gap> for entry in primdata do > if not IsBound( entry[2] ) then > s:= CharacterTable( entry[1] ); > poss:= Set( PossibleClassFusions( s, m ), > x -> InducedClassFunctionsByFusionMap( s, m, > [ TrivialCharacter( s ) ], x )[1] ); > entry[2]:= List( [ 1 .. NrConjugacyClasses( m ) ], > i -> Maximum( List( poss, x -> x[i] ) ) ); > fi; > od;
Now we estimate the lower bounds δ(s, g^G) introduced in Section 4.3-2. Let 𝕄 denote a set of representatives of the classes of maximal subgroups of M. Then
δ(s, g^G) = |s^G| - |s^G| ⋅ ∑_{S ∈ 𝕄} 1_S^M(s) ⋅ 1_S^M(g) / 1_S^M(1) ,
hence δ(s) can be computed from the corresponding primitive permutation characters, and a lower bound for δ(s) can be computed from the upper bounds for the characters 1_S^G which are given by the list primdata.
This means that modifying the output of LowerBoundsVertexDegrees as follows really yields lower bounds for the vertex degrees.
gap> prim:= List( primdata, x -> x[2] );; gap> classlengths:= SizesConjugacyClasses( m );; gap> bounds:= LowerBoundsVertexDegrees( classlengths, prim );;
Now we sum up the bounds for the individual classes. It turns out that the minimal vertex degree is more than 99.99998 percent of |M|. This proves that the generating graph of the Monster satisfies Pósa's criterion.
gap> degs:= List( bounds, Sum );; gap> Int( 100000000 * Minimum( degs ) / Size( m ) ); 99999987
Without the results from [DLP23], we can argue as follows. (This was the situation in earlier versions of this example file.)
According to [NW13], any maximal subgroup of the Monster is either among the 44 known classes from the above list except L_2(13).2 and U_3(4).4, or it is an almost simple group whose socle is one of L_2(13), Sz(8), U_3(4), and U_3(8).
We show that the elements of such subgroups are contained in the union of 55 conjugacy classes of the Monster that cover less than one percent of the elements in the Monster. For that, we compute the possible class fusions from the abovementioned simple groups S into the Monster, and then the possible class fusions from the automorphic extensions of S into the Monster, using the possible class fusions of S. (This approach is faster than computing each class fusion from scratch.)
After the following computations, the list badclasses will contain the positions of all those classes of M that may contain elements in some of the hypothetical maximal subgroups.
For each simple group in question, we enter the identifiers of the character tables of the automorphic extensions that can occur. Note that the automorphism groups of the four groups have the structures L_2(13).2, Sz(8).3, U_3(4).4, and U_3(8).(3 × S_3), respectively. We need not consider the groups U_3(8).3^2 and U_3(8).(3 × S_3) because already U_3(8).3_2 does not admit an embedding into M, and we need not consider the group U_3(8).S_3 because its set of elements is covered by its subgroups of the types U_3(8).2 and U_3(8).3_2.
gap> PossibleClassFusions( CharacterTable( "U3(8).3_2" ), m ); [ ] gap> badclasses:= [];; gap> names:= [ > [ "L2(13)", "L2(13).2" ], > [ "Sz(8)", "Sz(8).3" ], > [ "U3(4)", "U3(4).2", "U3(4).4" ], > [ "U3(8)", "U3(8).2", "U3(8).3_1", "U3(8).3_2", "U3(8).3_3", > "U3(8).6" ], > ];; gap> for list in names do > t:= CharacterTable( list[1] ); > tfusm:= PossibleClassFusions( t, m ); > UniteSet( badclasses, Flat( tfusm ) ); > for nam in list{ [ 2 .. Length( list ) ] } do > ext:= CharacterTable( nam ); > for map1 in PossibleClassFusions( t, ext ) do > inv:= InverseMap( map1 ); > for map2 in tfusm do > init:= CompositionMaps( map2, inv ); > UniteSet( badclasses, Flat( PossibleClassFusions( ext, m, > rec( fusionmap:= init ) ) ) ); > od; > od; > od; > od; gap> badclasses; [ 1, 3, 4, 5, 6, 7, 9, 10, 11, 12, 14, 15, 17, 18, 19, 20, 21, 22, 24, 25, 27, 28, 30, 32, 33, 35, 36, 38, 39, 40, 42, 43, 44, 45, 46, 48, 49, 50, 51, 52, 53, 54, 55, 56, 60, 61, 62, 63, 70, 72, 73, 78, 82, 85, 86 ] gap> Length( badclasses ); 55 gap> bad:= Sum( classlengths{ badclasses } ) / Size( m );; gap> Int( 10000 * bad ); 97
In the original version of this file, also hypothetical maximal subgroups with socle L_2(27) had been considered. As a consequence, the list badclasses computed above had length 59 in the original version; the list contained also the classes at the positions 90, 94, 95, and 96, that is, the classes 26B, 28B, 28C, 28D. The proportion bad of elements in the classes of M described by badclasses was about 2.05 percent of |M|, compared to the about 0.98 percent in the current version.
Now we estimate the lower bounds δ(s, g^G) introduced in Section 4.3-2. Let B denote the union of the classes described by badclasses, and let 𝕄 denote a set of representatives of the 44 known classes of maximal subgroups of M.
If s ∉ B then
δ(s, g^G) = |s^G| - |s^G| ⋅ ∑_{S ∈ 𝕄} 1_S^M(s) ⋅ 1_S^M(g) / 1_S^M(1) ,
hence δ(s) can be computed from the corresponding primitive permutation characters, and a lower bound for δ(s) can be computed from the upper bounds for the characters 1_S^G which are given by the list primdata.
If s ∈ B then the above equation for δ(s, g^G) holds at least for g ∉ B, so ∑_{g ∈ R ∖ B} δ(s, g^G) is a lower bound for δ(s). So primdata yields a lower bound for δ(s) also for s ∈ B, by ignoring the pairs (s, g) where both s and g lie in B.
This means that modifying the output of LowerBoundsVertexDegrees as follows really yields lower bounds for the vertex degrees. (Note that the row and column positions in the matrix returned by LowerBoundsVertexDegrees are shifted by one, compared to badclasses.)
gap> prim:= List( primdata, x -> x[2] );; gap> badpos:= Difference( badclasses, [ 1 ] ) - 1;; gap> bounds:= LowerBoundsVertexDegrees( classlengths, prim );; gap> for i in badpos do > for j in badpos do > bounds[i][j]:= 0; > od; > od;
Now we sum up the bounds for the individual classes. It turns out that the minimal vertex degree is more than 99 percent of |M|. This proves that the generating graph of the Monster satisfies Pósa's criterion.
(And the minimal vertex degree of elements outside B is more than 99.99998 percent of |M|.)
In the original version of this file, we got only 97.95 percent of |M| as the lower bound for the minimal vertex degree. The bound for elements outside B was the same in the original version. The fact that the maximal subgroups of type L_2(41) had been ignored in the original version did not affect the lower bound for the minimal vertex degree.
gap> degs:= List( bounds, Sum );; gap> Int( 10000 * Minimum( degs ) / Size( m ) ); 9902 gap> goodpos:= Difference( [ 1 .. NrConjugacyClasses( m ) - 1 ], > badpos );; gap> Int( 100000000 * Minimum( degs{ goodpos } ) / Size( m ) ); 99999987
Next we consider the nonsimple automorphism groups of the sporadic simple groups. Nontrivial outer automorphisms exist exactly in 12 cases, and then the simple group has index 2 in its automorphism group. The character tables of the groups and their maximal subgroups are available in GAP.
gap> spornames:= AllCharacterTableNames( IsSporadicSimple, true, > IsDuplicateTable, false );; gap> sporautnames:= AllCharacterTableNames( IsSporadicSimple, true, > IsDuplicateTable, false, > OfThose, AutomorphismGroup );; gap> sporautnames:= Difference( sporautnames, spornames ); [ "F3+.2", "Fi22.2", "HN.2", "HS.2", "He.2", "J2.2", "J3.2", "M12.2", "M22.2", "McL.2", "ON.2", "Suz.2" ] gap> for tbl in List( sporautnames, CharacterTable ) do > info:= HamiltonianCycleInfoFromCharacterTable( tbl ); > Print( Identifier( tbl ), ": ", info, "\n" ); > od; F3+.2: Chvatal for 0th closure, Posa for 1st closure Fi22.2: Chvatal for 0th closure, Posa for 1st closure HN.2: Chvatal for 0th closure, Posa for 1st closure HS.2: Chvatal for 1st closure, Posa for 2nd closure He.2: Chvatal for 0th closure, Posa for 1st closure J2.2: Chvatal for 0th closure, Posa for 1st closure J3.2: Chvatal for 0th closure, Posa for 1st closure M12.2: Chvatal for 0th closure, Posa for 1st closure M22.2: Posa for 1st closure McL.2: Chvatal for 0th closure, Posa for 1st closure ON.2: Chvatal for 0th closure, Posa for 1st closure Suz.2: Chvatal for 0th closure, Posa for 1st closure
For alternating and symmetric groups A_n and S_n, respectively, with 5 ≤ n ≤ 13, the table of marks or the character tables of the group and all its maximal subgroups are available in GAP. So we can compute the character-theoretic bounds for vertex degrees.
gap> for tbl in List( [ 5 .. 13 ], i -> CharacterTable( > Concatenation( "A", String( i ) ) ) ) do > info:= HamiltonianCycleInfoFromCharacterTable( tbl ); > if info <> "Posa for 0th closure" then > Print( Identifier( tbl ), ": ", info, "\n" ); > fi; > od;
No messages are printed, so the generating graphs of the alternating groups in question satisfy Pósa's criterion.
gap> for tbl in List( [ 5 .. 13 ], i -> CharacterTable( > Concatenation( "S", String( i ) ) ) ) do > info:= HamiltonianCycleInfoFromCharacterTable( tbl ); > Print( Identifier( tbl ), ": ", info, "\n" ); > od; A5.2: no decision A6.2_1: Chvatal for 4th closure, Posa for 5th closure A7.2: Posa for 1st closure A8.2: Chvatal for 2nd closure, Posa for 3rd closure A9.2: Chvatal for 2nd closure, Posa for 3rd closure A10.2: Chvatal for 2nd closure, Posa for 3rd closure A11.2: Posa for 1st closure A12.2: Chvatal for 2nd closure, Posa for 3rd closure A13.2: Posa for 1st closure
We see that sufficiently large closures of the generating graphs of the symmetric groups in question satisfy Pósa's criterion, except that the bounds for the symmetric group S_5 are not sufficient for the proof. In Section 4.5-2, it is shown that the 2nd closure of the generating graph of S_5 satisfies Pósa's criterion.
(We could find slightly better bounds derived only from character tables which suffice to prove that the generating graph for S_5 contains a Hamiltonian cycle, but this seems to be not worth while.)
We prove in Section 4.5-1 that the generating graphs of the nonabelian simple groups of order up to 10^6 satisfy Pósa's criterion, and that the same holds for those nonabelian simple groups of order between 10^6 and 10^7 that are not isomorphic with some PSL(2,q). (In Section 4.6, it is shown that the generating graph of PSL(2,q) satifies Pósa's criterion for any prime power q.) Nonsimple nonsolvable groups of order up to 10^6 are treated in Section 4.5-2.
(We could increase the bounds 10^6 and 10^7 with more computations, using the same methods.)
For our convenience, we provide a small function that takes as its argument only the group in question, and returns a string, the return value of HamiltonianCycleInfo for the vertex degrees computed from the group. (In order to speed up the computations, the function computes the proper normal subgroups that contain the derived subgroup of the given group, and enters the list of these groups as the third argument of VertexDegreesGeneratingGraph.)
gap> HamiltonianCycleInfoFromGroup:= function( G ) > local ccl, nsg, der, degrees, classlengths; > ccl:= ConjugacyClasses( G ); > if IsPerfect( G ) then > nsg:= []; > else > der:= DerivedSubgroup( G ); > nsg:= Concatenation( [ der ], > IntermediateSubgroups( G, der ).subgroups ); > fi; > degrees:= VertexDegreesGeneratingGraph( G, ccl, nsg ); > classlengths:= List( ccl, Size ); > return HamiltonianCycleInfo( classlengths, degrees ); > end;;
Representatives of the 56 isomorphism types of nonabelian simple groups of order up to 10^6 can be accessed in GAP with the function AllSmallNonabelianSimpleGroups.
gap> grps:= AllSmallNonabelianSimpleGroups( [ 1 .. 10^6 ] );; gap> Length( grps ); 56 gap> List( grps, StructureDescription ); [ "A5", "PSL(3,2)", "A6", "PSL(2,8)", "PSL(2,11)", "PSL(2,13)", "PSL(2,17)", "A7", "PSL(2,19)", "PSL(2,16)", "PSL(3,3)", "PSU(3,3)", "PSL(2,23)", "PSL(2,25)", "M11", "PSL(2,27)", "PSL(2,29)", "PSL(2,31)", "A8", "PSL(3,4)", "PSL(2,37)", "O(5,3)", "Sz(8)", "PSL(2,32)", "PSL(2,41)", "PSL(2,43)", "PSL(2,47)", "PSL(2,49)", "PSU(3,4)", "PSL(2,53)", "M12", "PSL(2,59)", "PSL(2,61)", "PSU(3,5)", "PSL(2,67)", "J1", "PSL(2,71)", "A9", "PSL(2,73)", "PSL(2,79)", "PSL(2,64)", "PSL(2,81)", "PSL(2,83)", "PSL(2,89)", "PSL(3,5)", "M22", "PSL(2,97)", "PSL(2,101)", "PSL(2,103)", "HJ", "PSL(2,107)", "PSL(2,109)", "PSL(2,113)", "PSL(2,121)", "PSL(2,125)", "O(5,4)" ] gap> for g in grps do > info:= HamiltonianCycleInfoFromGroup( g ); > if info <> "Posa for 0th closure" then > Print( StructureDescription( g ), ": ", info, "\n" ); > fi; > od;
Nothing is printed during these computations, so the generating graphs of all processed groups satisfy Pósa's criterion.
(On my notebook, the above computations needed about 6300 seconds of CPU time.)
For simple groups of order larger than 10^6, there is not such an easy way (yet) to access representatives for each isomorphism type. Therefore, first we compute the orders of nonabelian simple groups between 10^6 and 10^7.
gap> orders:= Filtered( [ 10^6+4, 10^6+8 .. 10^7 ], > n -> IsomorphismTypeInfoFiniteSimpleGroup( n ) <> fail ); [ 1024128, 1123980, 1285608, 1342740, 1451520, 1653900, 1721400, 1814400, 1876896, 1934868, 2097024, 2165292, 2328648, 2413320, 2588772, 2867580, 2964780, 3265920, 3483840, 3594432, 3822588, 3940200, 4245696, 4680000, 4696860, 5515776, 5544672, 5663616, 5848428, 6004380, 6065280, 6324552, 6825840, 6998640, 7174332, 7906500, 8487168, 9095592, 9732420, 9951120, 9999360 ] gap> Length( orders ); 41 gap> info:= List( orders, IsomorphismTypeInfoFiniteSimpleGroup );; gap> Number( info, x -> IsBound( x.series ) and x.series = "L" > and x.parameter[1] = 2 ); 31
We see that there are 31 groups of the type PSL(2,q) and 10 other nonabelian simple groups with order in the range from 10^6 to 10^7. The former groups can be ignored because the generating graphs of any group PSL(2,q) satisfies Pósa's criterion, see Section 4.6. For the latter groups, we can apply the character-theoretic method to prove that the generating graph satisfies Pósa's criterion.
gap> info:= Filtered( info, x -> not IsBound( x.series ) or > x.series <> "L" or x.parameter[1] <> 2 ); [ rec( name := "B(3,2) = O(7,2) ~ C(3,2) = S(6,2)", parameter := [ 3, 2 ], series := "B", shortname := "S6(2)" ), rec( name := "A(10)", parameter := 10, series := "A", shortname := "A10" ), rec( name := "A(2,7) = L(3,7) ", parameter := [ 3, 7 ], series := "L", shortname := "L3(7)" ), rec( name := "2A(3,3) = U(4,3) ~ 2D(3,3) = O-(6,3)", parameter := [ 3, 3 ], series := "2A", shortname := "U4(3)" ), rec( name := "G(2,3)", parameter := 3, series := "G", shortname := "G2(3)" ), rec( name := "B(2,5) = O(5,5) ~ C(2,5) = S(4,5)", parameter := [ 2, 5 ], series := "B", shortname := "S4(5)" ), rec( name := "2A(2,8) = U(3,8)", parameter := [ 2, 8 ], series := "2A", shortname := "U3(8)" ), rec( name := "2A(2,7) = U(3,7)", parameter := [ 2, 7 ], series := "2A", shortname := "U3(7)" ), rec( name := "A(3,3) = L(4,3) ~ D(3,3) = O+(6,3) ", parameter := [ 4, 3 ], series := "L", shortname := "L4(3)" ), rec( name := "A(4,2) = L(5,2) ", parameter := [ 5, 2 ], series := "L", shortname := "L5(2)" ) ] gap> names:= [ "S6(2)", "A10", "L3(7)", "U4(3)", "G2(3)", "S4(5)", > "U3(8)", "U3(7)", "L4(3)", "L5(2)" ];; gap> for tbl in List( names, CharacterTable ) do > info:= HamiltonianCycleInfoFromCharacterTable( tbl ); > if info <> "Posa for 0th closure" then > Print( Identifier( tbl ), ": ", info, "\n" ); > fi; > od;
Let G be a nonsolvable group such that G/N is cyclic for all nontrivial normal subgroups N of G. Then the socle Soc(G) of G is the unique minimal normal subgroup. Moreover, Soc(G) is nonsolvable and thus a direct product of isomorphic nonabelian simple groups, and G is isomorphic to a subgroup of Aut(Soc(G)).
In order to deal with all such groups G for which additionally |Soc(G)| ≤ 10^6 holds, it is sufficient to run over the simple groups S of order up to 10^6 and to consider those subgroups G of Aut(S^n), with |S|^n ≤ 10^6, for which Inn(G) is the unique minimal normal subgroup and G /Inn(G) is cyclic.
We show that for each such group, a sufficient closure of the generating graph satisfies Pósa's criterion.
gap> grps:= AllSmallNonabelianSimpleGroups( [ 1 .. 10^6 ] );; gap> epi:= "dummy";; # Avoid a message about an unbound variable ... gap> for simple in grps do > for n in [ 1 .. LogInt( 10^6, Size( simple ) ) ] do > # Compute the n-fold direct product S^n. > soc:= CallFuncList( DirectProduct, > ListWithIdenticalEntries( n, simple ) ); > # Compute Aut(S^n) as a permutation group. > aut:= Image( IsomorphismPermGroup( AutomorphismGroup( soc ) ) ); > aut:= Image( SmallerDegreePermutationRepresentation( aut ) ); > # Compute class representatives of subgroups of > # Aut(S^n)/Inn(S^n). > socle:= Socle( aut ); > epi:= NaturalHomomorphismByNormalSubgroup( aut, socle ); > # Compute the candidates for G. (By the above computations, > # we need not consider simple groups.) > reps:= List( ConjugacyClassesSubgroups( Image( epi ) ), > Representative ); > reps:= Filtered( reps, x -> IsCyclic( x ) and Size( x ) <> 1 ); > greps:= Filtered( List( reps, x -> PreImages( epi, x ) ), > x -> Length( MinimalNormalSubgroups( x ) ) = 1 ); > for g in greps do > # We have to deal with a *transitive* permutation group. > # (Each group in question acts faithfully on an orbit.) > if not IsTransitive( g ) then > g:= First( List( Orbits( g, MovedPoints( g ) ), > x -> Action( g, x ) ), > x -> Size( x ) = Size( g ) ); > fi; > # Check this group G. > info:= HamiltonianCycleInfoFromGroup( g ); > Print( Name( simple ), "^", n, ".", Size( g ) / Size( soc ), > ": ", info, "\n" ); > od; > od; > od; A5^1.2: Posa for 2nd closure A5^2.2: Posa for 0th closure A5^2.4: Posa for 0th closure A5^3.3: Posa for 0th closure A5^3.6: Chvatal for 1st closure, Posa for 2nd closure PSL(2,7)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,7)^2.2: Posa for 0th closure PSL(2,7)^2.4: Posa for 0th closure A6^1.2: Chvatal for 0th closure, Posa for 1st closure A6^1.2: Chvatal for 4th closure, Posa for 5th closure A6^1.2: Chvatal for 0th closure, Posa for 1st closure A6^2.2: Posa for 0th closure A6^2.4: Posa for 0th closure A6^2.4: Posa for 0th closure A6^2.4: Posa for 0th closure PSL(2,8)^1.3: Posa for 0th closure PSL(2,8)^2.2: Posa for 0th closure PSL(2,8)^2.6: Chvatal for 0th closure, Posa for 1st closure PSL(2,11)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,11)^2.2: Posa for 0th closure PSL(2,11)^2.4: Posa for 0th closure PSL(2,13)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,17)^1.2: Chvatal for 0th closure, Posa for 1st closure A7^1.2: Posa for 1st closure PSL(2,19)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,16)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,16)^1.4: Chvatal for 0th closure, Posa for 1st closure PSL(3,3)^1.2: Chvatal for 0th closure, Posa for 1st closure PSU(3,3)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,23)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,25)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,25)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,25)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,27)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,27)^1.3: Posa for 0th closure PSL(2,27)^1.6: Chvatal for 0th closure, Posa for 1st closure PSL(2,29)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,31)^1.2: Chvatal for 0th closure, Posa for 1st closure A8^1.2: Chvatal for 2nd closure, Posa for 3rd closure PSL(3,4)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(3,4)^1.2: Chvatal for 1st closure, Posa for 2nd closure PSL(3,4)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(3,4)^1.3: Posa for 0th closure PSL(3,4)^1.6: Chvatal for 0th closure, Posa for 1st closure PSL(2,37)^1.2: Chvatal for 0th closure, Posa for 1st closure PSp(4,3)^1.2: Chvatal for 1st closure, Posa for 2nd closure Sz(8)^1.3: Posa for 0th closure PSL(2,32)^1.5: Posa for 0th closure PSL(2,41)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,43)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,47)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,49)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,49)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,49)^1.2: Chvatal for 0th closure, Posa for 1st closure PSU(3,4)^1.2: Chvatal for 0th closure, Posa for 1st closure PSU(3,4)^1.4: Chvatal for 0th closure, Posa for 1st closure PSL(2,53)^1.2: Chvatal for 0th closure, Posa for 1st closure M12^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,59)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,61)^1.2: Chvatal for 0th closure, Posa for 1st closure PSU(3,5)^1.2: Chvatal for 0th closure, Posa for 1st closure PSU(3,5)^1.3: Posa for 0th closure PSL(2,67)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,71)^1.2: Chvatal for 0th closure, Posa for 1st closure A9^1.2: Chvatal for 2nd closure, Posa for 3rd closure PSL(2,73)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,79)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,64)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,64)^1.3: Posa for 0th closure PSL(2,64)^1.6: Chvatal for 0th closure, Posa for 1st closure PSL(2,81)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,81)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,81)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,81)^1.4: Chvatal for 0th closure, Posa for 1st closure PSL(2,81)^1.4: Chvatal for 0th closure, Posa for 1st closure PSL(2,83)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,89)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(3,5)^1.2: Chvatal for 0th closure, Posa for 1st closure M22^1.2: Posa for 1st closure PSL(2,97)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,101)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,103)^1.2: Chvatal for 0th closure, Posa for 1st closure J_2^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,107)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,109)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,113)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,121)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,121)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,121)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,125)^1.2: Chvatal for 0th closure, Posa for 1st closure PSL(2,125)^1.3: Posa for 0th closure PSL(2,125)^1.6: Chvatal for 0th closure, Posa for 1st closure PSp(4,4)^1.2: Chvatal for 0th closure, Posa for 1st closure PSp(4,4)^1.4: Posa for 0th closure
We show that the generating graph of any group PSL(2,q), for q ≥ 2, satisfies Pósa's criterion. Throughout this section, let q = p^f for a prime integer p, and G = PSL(2,q). Set k = gcd(q-1, 2).
Lemma 1: (see [Hup67, II., § 8]) The subgroups of G are
cyclic groups of order dividing (q ± 1)/k, and their normalizers, which are dihedral groups of order 2 (q ± 1)/k,
subgroups of Sylow p normalizers, which are semidirect products of elementary abelian groups of order q with cyclic groups of order (q-1)/k,
subgroups isomorphic with PSL(2, p^m) if m divides f, and isomorphic with PGL(2, p^m) if 2 m divides f,
subgroups isomorphic with A_4, S_4, or A_5, for appropriate values of q.
G contains exactly one conjugacy class of cyclic subgroups of each of the orders (q-1)/k and (q+1)/k, and each nonidentity element of G is contained in exactly one of these subgroups or in exactly one Sylow p subgroup of G.
We estimate the number of elements that are contained in subgroups of type (3).
Lemma 2: Let n_sf(q) denote the number of those nonidentity elements in G that are contained in proper subgroups of type (3). Then n_sf(q) ≤ q^2 (2 p (sqrtq-1) / (p-1) - 1). If f is a prime then n_sf(q) ≤ (2p-1) q^2 holds, and if p = q then we have of course n_sf(q) = 0.
Proof: The group PGL(2, p^m) is equal to PSL(2, p^m) for p = 2, and contains PSL(2, p^m) as a subgroup of index two if p ne 2. So the largest element order in PGL(2, p^m) is at most p^m+1. Let C be a cyclic subgroup of order (q + ϵ)/k in G, for ϵ ∈ { ± 1 }. The intersection of C with any subgroup of G isomorphic with PGL(2, p^m) or PSL(2, p^m) is contained in the union of the unique subgroups of the orders gcd(|C|, p^m + 1) and gcd(|C|, p^m - 1) in C. So C contains at most 2 p^m - 2 nonidentity elements that can lie inside subgroups isomorphic with PGL(2, p^m) or PSL(2, p^m). Hence C contains at most ∑_m (2 p^m - 2) nonidentity elements in proper subgroups of type (3), where m runs over the proper divisors of f. This sum is bounded from above by ∑_{m=1}^{f/2} (2 p^m - 2) ≤ 2 p (sqrt{q}-1) / (p-1) - 2.
The numbers of cyclic subgroups of the orders (q + ϵ)/k in G are q (q - ϵ) / 2, so G contains altogether q^2 such cyclic subgroups. They contain at most q^2 (2 p (sqrt{q}-1) / (p-1) - 2) elements inside proper subgroups of the type (3).
All elements of order p in G are contained in subgroups of type (3), and there are exactly q^2 - 1 such elements. This yields the claimed bound for n_sf(q). The better bound for the case that f is a prime follows from ∑_m (2 p^m - 2) = 2 p - 2 if m ranges over the proper divisors of f. ▒
Using these bounds, we see that the vertex degree of any element in G that does not lie in subgroups of type (4) is larger than |G|/2. (In fact we could use the calculations below to derive a better asymptotic bound, but this is not an issue here.)
Lemma 3: Let s ∈ G be an element of order larger than 5. Then |{ g ∈ G; ⟨ g, s ⟩ = G }| > |G|/2.
Proof: First suppose that the order of s divides (q+1)/k or (q-1)/k. If g ∈ G such that U = ⟨ s, g ⟩ is a proper subgroup of G then U ≤ N_G(⟨ s ⟩) or U lies in a Sylow p normalizer of G or U lies in a subgroup of type (3). Since s is contained in at most two Sylow p normalizers (each Sylow p normalizer contains q cyclic subgroups of order (q-1)/k, and G contains q+1 Sylow normalizers and q (q+1)/2 cyclic subgroups of order (q-1)/k), the number of g ∈ G with the property that ⟨ s, g ⟩ ≠ G is at most N = 2(q+1)/k + 2 q(q-1)/k + n_sf(q) = 2(q^2+1)/k + n_sf(q); for s of order equal to (q+1)/k or (q-1)/k, we can set N = 2(q^2+1)/k.
Any element s of order p (larger than 5), lies only in a unique Sylow p normalizer and in subgroups of type (3), so the bound N holds also in this case.
For f = 1, N is smaller than |G|/2 = q (q^2-1) / (2 k) if q ≥ 5. (The statement of the lemma is trivially true for q ≤ 5.)
For primes f, N is smaller than |G|/2 if q^2 (q-8p) > q+4 holds, which is true for p^f > 8p. Only the following values of p^f with prime f do not satisfy this condition: 2^2 and 3^2 (where no element of order larger than 5 exists), 2^3 (where only elements of order equal to q ± 1 must be considered), 5^2 and 7^2 (where n_sf(q) < (p-1) q (q+1) because in these cases the cyclic subgroups of order (q+1)/k cannot contain nonidentity elements in subgroups of type (3)).
Finally, if f is not a prime then N is smaller than |G|/2 if q^2 (q - 8p (sqrt{q}-1) / (p-1)) > q+4 holds, which is true for q ≥ 256. The only values of p^f with non-prime f that do not satisfy this condition are 2^4, 2^6, and 3^4. In all three cases, we have in fact N < |G|/2, where we have to use the better bound n_sf(q) < 16 q^2 in the third case. ▒
In order to show that the generating graph of G satisfies Pósa's criterion, it suffices to show that the vertex degrees of involutions is larger than the number of involutions, and that the vertex degrees of elements of orders 2, 3, 4, and 5 are larger than the number of elements whose order is at most 5.
Lemma 4: Let n(q, m) denote the number of elements of order m in G, and let φ(m) denote the number of prime residues modulo m.
We have n(q, 2) = q^2 - 1 if q is even and n(q, 2) ≤ q (q+1)/2 if q is odd.
For m ∈ { 3, 4, 5 }, we have n(q, m) ≤ φ(m) q (q+1)/2.
We have n(q, (q+1)/k) = φ((q+1)/k) q (q-1)/2.
Lemma 5: If q > 11 then each involution in G has vertex degree larger than n(q, 2).
If φ((q+1)/k) ≥ 12 then each element of order 3, 4, or 5 has vertex degree larger than ∑_{m=2}^5 n(q, m).
Proof: Let s ∈ G of order at most 5. For each element g ∈ G of order (q+1)/k, U = ⟨ g, s ⟩ is either G or contained in the dihedral group of order 2(q+1)/k that normalizes ⟨ g ⟩.
If s is an involution then the number of such dihedral groups that contain s is at most (q+3)/2, and at least n(q, (q+1)/k) - φ((q+1)/k) (q+3)/2 = φ((q+1)/k) (q^2-2q-3)/2 elements of order (q+1)/k contribute to the vertex degree of s. This number is larger than q^2 - 1 ≥ n(q, 2) if q > 11 (and hence φ((q+1)/k) ≥ 3) holds.
If s is an element of order 3, 4, or 5 then U ≠ G means that s ∈ ⟨ g ⟩, so at least n(q, (q+1)/k) - 4 elements of order (q+1)/k contribute to the vertex degree of s. This number is larger than 5 q (q+1) > ∑_{m=2}^5 n(q, m) if φ((q+1)/k) ≥ 12. ▒
It remains to deal with the values q where φ((q+1)/k) < 12, that is, (q+1)/k ≤ 30. We compute that the statement of Lemma 5 is true also for prime powers q with 11 < q ≤ 59.
gap> TestL2q:= function( t ) > local name, orders, nccl, cl, prim, bds, n, ord; > > name:= Identifier( t ); > orders:= OrdersClassRepresentatives( t ); > nccl:= Length( orders ); > cl:= SizesConjugacyClasses( t ); > prim:= PrimitivePermutationCharacters( t ); > bds:= List( LowerBoundsVertexDegrees( cl, prim ), Sum ); > n:= List( [ 1 .. 5 ], i -> Sum( cl{ Filtered( [ 1 .. nccl ], > x -> orders[x] = i ) } ) ); > if ForAny( Filtered( [ 1 .. nccl ], i -> orders[i] > 5 ), > i -> bds[i-1] <= Size( t ) / 2 ) then > Error( "problem with large orders for ", name ); > elif ForAny( Filtered( [ 1 .. nccl ], i -> orders[i] = 2 ), > i -> bds[i-1] <= n[2] ) then > Error( "problem with order 2 for ", name, "\n" ); > elif ForAny( Filtered( [ 1 .. nccl ], > i -> orders[i] in [ 3 .. 5 ] ), > i -> bds[i-1] <= Sum( n{ [ 2 .. 5 ] } ) ) then > Error( "problem with order in [ 3 .. 5 ] for ", name ); > fi; > end;; gap> for q in Filtered( [ 13 .. 59 ], IsPrimePowerInt ) do > TestL2q( CharacterTable( > Concatenation( "L2(", String( q ), ")" ) ) ); > od;
For 2 ≤ q ≤ 11, the statement of Lemma 5 is not true but Pósa's criterion is satisfied for the generating graphs of the groups PSL(2,q) with 2 ≤ q ≤ 11.
gap> for q in Filtered( [ 2 .. 11 ], IsPrimePowerInt ) do > info:= HamiltonianCycleInfoFromGroup( PSL( 2, q ) ); > if info <> "Posa for 0th closure" then > Print( q, ": ", info, "\n" ); > fi; > od;
generated by GAPDoc2HTML